Entendendo os Modelos de Equilíbrio Geral Dinâmico Estocástico (DSGE)

segunda-feira, 3 de agosto de 2015

Código cap 7

//Modelo NK com Governo - Capítulo 7 (ENTENDENDO OS MODELOS DSGE)

var Y IP IG C CR CNR G
KP KG L LR LNR
R W CM P PI PIW Q RB LAMBDAR LAMBDANR
T tau_c tau_k tau_l TRANS B
A Sm SG SIG STRANS Stau_c Stau_l Stau_k U;

varexo e e_m e_G e_IG e_TRANS e_tau_c e_tau_l e_tau_k;

parameters sigma phi alpha1 alpha2 alpha3 beta delta
deltaG rhoa psi theta thetaW psiW
rhoG rhoIG rhoTRANS rhotau_c rhotau_l rhotau_k rhom
gammaG gammaIG gammaTRANS gammatau_c gammatau_l gammatau_k
phiG phiIG phiTRANS phitau_c phitau_l phitau_k
gammaR gammaPI gammaY tau_css tau_lss tau_kss phic omegaR Psi1 Psi2 chi;

alpha1 = 0.3;
alpha2 = 0.65;
alpha3 = 0.05;
beta = 0.985;
delta = 0.025;
deltaG = 0.025;
theta = 0.75;
thetaW = 0.75;
sigma = 2;
phi = 1.5;
psi = 8;
psiW = 21;
tau_css = 0.16;
tau_lss = 0.17;
tau_kss = 0.08;
phic = 0.8;
omegaR = 0.5;
Psi2 = 1;
chi = 1;
//Parâmetros de Política Fiscal
gammaG = 0;
gammaIG = 0.1;
gammaTRANS = 0.1;
gammatau_c = 0;
gammatau_l = 0;
gammatau_k = 0;
phiG = 0;
phiIG = -0.1;
phiTRANS = -0.1;
phitau_c = 0;
phitau_l = 0;
phitau_k = 0;
//Parâmetros da Regra de Taylor
gammaR = 0.8;
gammaY = 0.5;
gammaPI = 1.5;
//Parâmetros autoregressivos dos Choques
rhoa = 0.9;
rhoG = 0.9;
rhoIG = 0.9;
rhoTRANS = 0.9;
rhotau_c = 0.9;
rhotau_l = 0.9;
rhotau_k = 0.9;
rhom = 0.9;
//
Psi1 = (1+tau_css)*((1/beta)-(1-delta));

model(linear);
#phiB = 1;
#phi_TRANS=0.01;
#phi_IG=0.02;
#Uss = 1;
#Pss = 1;
#PIss = 1;
#RBss = 1/beta;
#Rss = Pss*((1+tau_css)/(1-tau_kss))*((1/beta)-(1-delta));
#CMss = ((psi-1)/psi)*(1-beta*theta)*Pss;
#Wss = alpha2*((CMss*0.2^alpha3)^(1/alpha2))*((alpha1/Rss)^(alpha1/alpha2));
#A1 = ((1-phic*beta)*((1-phic)^(-sigma))*(1-beta*thetaW)*((psiW-1)/psiW)
*((1-tau_lss)/(1+tau_css))*(Wss/Pss)*(Wss/(alpha2*CMss))^phi)^(1/sigma);
#A2 = (((Rss*(Pss-tau_lss*(1-alpha1)*CMss)-tau_kss*(Rss-delta)
*alpha1*CMss)/(Pss*Rss*(1+tau_css)))-(delta*alpha1*CMss/Rss)
-(phiB/Pss)*((1/RBss)-1)+phi_TRANS);
#Yss = (A1/A2)^(sigma/(sigma+phi));
#Bss = phiB*Yss;
#Lss = alpha2*CMss*(Yss/Wss);
#LRss = Lss;
#LNRss = Lss;
#KPss = alpha1*CMss*(Yss/Rss);
#IPss = delta*KPss;
#IGss = phi_IG*Yss;
#KGss = IGss/deltaG;
#Css = (1/(Yss^(phi/sigma)))*A1;
#CRss = Css;
#CNRss = Css;
#Gss = Yss - IPss - IGss - Css;
#TRANSss = phiTRANS*Yss;
#Tss = Pss*Gss + Pss*IGss + Pss*TRANSss - Bss*((1/RBss)-1);
#LAMBDARss = ((CRss^(-sigma))*(1-phic*beta)
*(1-phic)^(-sigma))/((1+tau_css)*Pss);
#LAMBDANRss = ((CNRss^(-sigma))*(1-phic*beta)
*(1-phic)^(-sigma))/((1+tau_css)*Pss);
#Qss = LAMBDARss*Pss*(1+tau_css);
//1-Lagrangiano da família ricardiana
LAMBDAR + P + (tau_css/(1+tau_css))*tau_c = (sigma/((1-phic)
*(1-phic*beta)))*(phic*beta*(CR(+1)-CR)-(CR-CR(-1)));
//2-Equação de Phillips para os salários da família ricardiana
PIW = beta*PIW(+1)+((1-thetaW)*(1-beta*thetaW)/thetaW)
*(phi*LR-LAMBDAR+(tau_lss/(1-tau_lss))*tau_l);
//3-Taxa de inflação bruta dos salários
PIW = W - W(-1);
//4 - Restrição orçamentária da família ricardiana
Pss*CRss*((P+CR)*(1+tau_css)+tau_css*tau_c) + Pss*IPss*((P+IP)
*(1+tau_css)+tau_css*tau_c) + (Bss/RBss)*(B-RB) = Wss*LRss
*((W+LR)*(1-tau_lss)-tau_lss*tau_l)+Rss*KPss*((R+KP(-1))
*(1-tau_kss)-tau_kss*tau_k) + Bss*B(-1) + omegaR*TRANSss*TRANS;
//5-Q de Tobin
(Qss/beta)*Q = (1-delta)*Qss*Q(+1) + LAMBDARss*Rss*Uss
*(1-tau_kss)*(LAMBDAR(+1)+R(+1)+U(+1)-(tau_kss/(1-tau_kss))
*tau_k(+1))-LAMBDARss*Pss*Uss*Psi1*U(+1);
//6-Demanda por capacidade instalada
(1-tau_kss)*(Rss/Pss)*(R-P-(tau_kss/(1-tau_kss))*tau_k)=Psi2*Uss*U;
//7-Demanda por investimentos
(1+tau_css)*LAMBDARss*Pss*(LAMBDAR+P+(tau_css/(1+tau_css))*tau_c)
-Qss*Q+chi*Qss*(IP-IP(-1))=chi*beta*Qss*(IP(+1)-IP);
//8-Lei de movimento do capital privado
KP = (1-delta)*KP(-1) + delta*IP;
//9-Equação de Euler (Título público)
LAMBDAR - RB = LAMBDAR(+1);
//10-Lagrangiano da família não ricardiana
LAMBDANR + P + (tau_css/(1+tau_css))*tau_c
= (sigma/((1-phic)*(1-phic*beta)))*(phic*beta*(CNR(+1)-CNR)-(CNR-CNR(-1)));
//11-Equação de Phillips para os salários da família não ricardiana
PIW = beta*PIW(+1)+((1-thetaW)*(1-beta*thetaW)/thetaW)
*(phi*LNR-LAMBDANR+(tau_lss/(1-tau_lss))*tau_l);
//12-Consumo Agregado
Css*C = omegaR*CRss*CR + (1-omegaR)*CNRss*CNR;
//13-Trabalho Agregado
Lss*L = omegaR*LRss*LR + (1-omegaR)*LNRss*LNR;
//14-Função de Produção
Y = A + alpha1*(U+KP(-1)) + alpha2*L + alpha3*KG(-1);
//15- Tradeoff do problema das firmas (TMS=Preço relativo)
L - U - KP(-1) = R - W;
//16-Custo Marginal
CM = alpha2*W + alpha1*R - A - alpha3*KG(-1);
//17-Equação de Phillips
PI = beta*PI(+1) + ((1-theta)*(1-beta*theta)/theta)*(CM-P);
//18-Taxa de inflação bruta
PI(+1) = P(+1) - P;
//19-Restrição orçamentária do governo
(Bss/RBss)*(B-RB)-Bss*B(-1) + Tss*T = Pss*Gss*(P+G)
+ Pss*IGss*(P+IG) + Pss*TRANSss*(P+TRANS);
//20-Receita de tributos do governo
Tss*T = tau_css*Pss*(Css*(C+P+tau_c)+IPss*(IP+P+tau_c))
+tau_lss*Wss*Lss*(W+L+tau_l)
+tau_kss*KPss*(Rss*(R+KP(-1)+tau_k)-delta*(KP(-1)+tau_k));
//21-Regra de movimento do capital público
KG = (1-deltaG)*KG(-1) + deltaG*IG;
//22-Regra de Movimento dos Gastos Públicos
G = gammaG*G(-1) + (1-gammaG)*phiG*(B(-1)-Y(-1)-P(-1))+SG;
//23-Regra de Movimento dos Investimentos Públicos
IG = gammaIG*IG(-1) + (1-gammaIG)*phiIG*(B(-1)-Y(-1)-P(-1))+SIG;
//24-Regra de Movimento das Transferências de Renda
TRANS = gammaTRANS*TRANS(-1) + (1-gammaTRANS)
*phiTRANS*(B(-1)-Y(-1)-P(-1))+STRANS;
//25-Regra de Movimento do tributo sobre Consumo
tau_c = gammatau_c*tau_c(-1) + (1-gammatau_c)
*phitau_c*(B(-1)-Y(-1)-P(-1))+Stau_c;
//26-Regra de Movimento do tributo sobre a Renda do Trabalho
tau_l = gammatau_l*tau_l(-1) + (1-gammatau_l)
*phitau_l*(B(-1)-Y(-1)-P(-1))+Stau_l;
//27-Regra de Movimento do tributo sobre Consumo
tau_k = gammatau_k*tau_k(-1) + (1-gammatau_k)
*phitau_k*(B(-1)-Y(-1)-P(-1))+Stau_k;
//28-Regra de Taylor
RB = gammaR*RB(-1)+(1-gammaR)*(gammaPI*PI + gammaY*Y)+Sm;
//29-Condição de equilíbrio
Yss*Y = Css*C + IPss*IP + IGss*IG + Gss*G;
//30-Choque de produtividade
A = rhoa*A(-1) + e;
//31 - Choque nos Gastos Públicos
SG = rhoG*SG(-1) + e_G;
//32 - Choque nos Insvestimentos Públicos
SIG = rhoIG*SIG(-1) + e_IG;
//33 - Choque na Transferências de Renda
STRANS = rhoTRANS*STRANS(-1) + e_TRANS;
//34 - Choque no tributo sobre o Consumo
Stau_c = rhotau_c*Stau_c(-1) - e_tau_c;
//35 - Choque no tributo sobre a Renda do Trabalho
Stau_l = rhotau_l*Stau_l(-1) - e_tau_l;
//36 - Choque no tributo sobre a Renda do Capital
Stau_k = rhotau_k*Stau_k(-1) - e_tau_k;
//37- Choque Monetário
Sm = rhom*Sm(-1)-e_m;
end;

steady;
check(qz_zero_threshold=1e-20);

shocks;
var e; stderr 0.01;
var e_G; stderr 0.01;
var e_IG; stderr 0.01;
var e_TRANS; stderr 0.01;
var e_tau_c; stderr 0.01;
var e_tau_l; stderr 0.01;
var e_tau_k; stderr 0.01;
var e_m; stderr 0.01;
end;

stoch_simul(periods=1000,qz_zero_threshold=1e-20)
Y IP IG CR CNR G KP KG LR LNR R W U PI RB T B tau_c tau_k tau_l TRANS A;

Código cap 6

//Modelo NK com Rigidez nos Investimentos
//(Custos no ajuste do Investimento e na
//não utilização da capacidade instalada máxima)
//- Capítulo 6 (ENTENDENDO OS MODELOS DSGE)

var Y I C CR CNR R K W L LR LNR PIW P PI A LAMBDAR LAMBDANR Q U CM;
varexo e;
parameters sigma phi alpha beta delta rhoa psi theta
thetaW psiW phic omegaR Psi1 Psi2 chi;

sigma = 2;
phi = 1.5;
alpha = 0.35;
beta = 0.985;
delta = 0.025;
rhoa = 0.95;
psi = 8;
theta = 0.75;
thetaW = 0.75;
psiW = 21;
phic = 0.8;
omegaR = 0.5;
Psi1 = ((1/beta)-(1-delta));
Psi2 = 1;
chi = 1;

model(linear);
#Uss = 1;
#Pss = 1;
#Rss = Pss*Psi1;
#CMss = ((psi-1)/psi)*(1-beta*theta)*Pss;
#Wss = (1-alpha)*(CMss^(1/(1-alpha)))*((alpha/Rss)^(alpha/(1-alpha)));
#Yss = ((Rss/(Rss-delta*alpha*CMss))^(sigma/(sigma+phi)))*((1-phic*beta)
*((1-phic)^(-sigma))*(1-beta*thetaW)*((psiW-1)/psiW)*(Wss/Pss)
*(Wss/((1-alpha)*CMss))^phi)^(1/(sigma+phi));
#Kss = alpha*CMss*(Yss/Rss);
#Iss = delta*Kss;
#Css = Yss - Iss;
#Lss = (1-alpha)*CMss*(Yss/Wss);
#CRss = Css;
#CNRss = Css;
#LRss = Lss;
#LNRss = Lss;
#LAMBDARss = (1/Pss)*(CRss^(-sigma))*((1-phic)^(-sigma))*(1-phic*beta);
#LAMBDANRss = (1/Pss)*(CNRss^(-sigma))*((1-phic)^(-sigma))*(1-phic*beta);
#Qss = Pss*LAMBDARss;
//1-Lagrangiano da família ricardiana
LAMBDAR = (sigma/((1-phic)*(1-phic*beta)))
*(phic*beta*(CR(+1)-phic*CR)-(CR-phic*CR(-1)))-P;
//2-Equação de Phillips para os salários da família ricardiana
PIW = beta*PIW(+1)+((1-thetaW)*(1-beta*thetaW)/thetaW)*(LR-LAMBDAR-W);
//3-Taxa de inflação bruta dos salários
PIW = W - W(-1);
//4-Q de Tobin
(Qss/beta)*Q = (1-delta)*Qss*Q(+1)+LAMBDARss*Rss*Uss
*(LAMBDAR(+1)+R(+1)+U(+1))-LAMBDARss*Pss*Psi1*Uss*U(+1);
//5-Demanda por Capacidade Instalada
(Rss/Pss)*(R-P) = Psi2*Uss*U;
//6-Demanda por Investimentos
LAMBDARss*Pss*(LAMBDAR+P)-Qss*Q+chi*Qss*(I-I(-1))=chi*beta*Qss*(I(+1)-I);
//7-Lei de Movimento do Capital
K = (1-delta)*K(-1) + delta*I;
//8-Lagrangiano da família não ricardiana
LAMBDANR = (sigma/((1-phic)*(1-phic*beta)))
*(phic*beta*(CNR(+1)-phic*CNR)-(CNR-phic*CNR(-1)))-P;
//9-Equação de Phillips para os salários da família não ricardiana
PIW = beta*PIW(+1)+((1-thetaW)*(1-beta*thetaW)/thetaW)*(LNR-LAMBDANR-W);
//10-Restrição orçamentária da família não ricardiana
P+CNR=W+LNR;
//11-Consumo agregado
Css*C = omegaR*CRss*CR + (1-omegaR)*CNRss*CNR;
//12-Trabalho agregado
Lss*L = omegaR*LRss*LR + (1-omegaR)*LNRss*LNR;
//13-Função de produção
Y = A + alpha*(U+K(-1)) + (1-alpha)*L;
//14-Demanda por capital
U + K(-1) = Y - R;
//15-Demanda por trabalho
L = Y - W;
//16-Custo marginal
CM = ((1-alpha)*W + alpha*R - A);
//17-Equação de Phillips
PI = beta*PI(+1)+((1-theta)*(1-beta*theta)/theta)*(CM-P);
//18-Taxa de inflação bruta
PI = P - P(-1);
//19-Condição de equilíbrio
Yss*Y = Css*C + Iss*I;
//20-Choque de produtividade
A = rhoa*A(-1) + e;
end;

model_diagnostics;
steady;
check (qz_zero_threshold=1e-20);

shocks;
var e;
stderr 0.01;
end;

stoch_simul(qz_zero_threshold=1e-20)
Y I C CR CNR R K W L LR LNR PIW PI Q U A;

Código cap 5

//Modelo NK com Rigidez nas Famílias
//(formação de hábitos e Agentes não Ricardianos)
//Capítulo 5 (ENTENDENDO OS MODELOS DSGE)
var Y I C CR CNR R K W L LR LNR PIW P PI A LAMBDAR LAMBDANR CM;
varexo e;
parameters sigma phi alpha beta delta rhoa psi theta thetaW psiW phic omegaR;

sigma = 2;
phi = 1.5;
alpha = 0.35;
beta = 0.985;
delta = 0.025;
rhoa = 0.95;
psi = 8;
theta = 0.75;
thetaW = 0.75;
psiW = 21;
phic = 0.8;
omegaR = 0.5;

model(linear);
#Pss = 1;
#Rss = Pss*((1/beta)-(1-delta));
#CMss = ((psi-1)/psi)*(1-beta*theta)*Pss;
#Wss = (1-alpha)*(CMss^(1/(1-alpha)))*((alpha/Rss)^(alpha/(1-alpha)));
#Yss = ((Rss/(Rss-delta*alpha*CMss))^(sigma/(sigma+phi)))
*((1-phic*beta)*((1-phic)^(-sigma))*(1-beta*thetaW)*((psiW-1)/psiW)*(Wss/Pss)
*(Wss/((1-alpha)*CMss))^phi)^(1/(sigma+phi));
#Kss = alpha*CMss*(Yss/Rss);
#Iss = delta*Kss;
#Css = Yss - Iss;
#Lss = (1-alpha)*CMss*(Yss/Wss);
#CRss = Css;
#CNRss = Css;
#LRss = Lss;
#LNRss = Lss;
#LAMBDARss = (1/Pss)*(CRss^(-sigma))*((1-phic)^(-sigma))*(1-phic*beta);
#LAMBDANRss = (1/Pss)*(CNRss^(-sigma))*((1-phic)^(-sigma))*(1-phic*beta);
//1-Lagrangiano da família ricardiana
LAMBDAR = (sigma/((1-phic)*(1-phic*beta)))*(phic*beta*(CR(+1)-phic*CR)
-(CR-phic*CR(-1)))-P;
//2-Equação de Phillips para os salários da família ricardiana
PIW = beta*PIW(+1)+((1-thetaW)*(1-beta*thetaW)/thetaW)*(LR-LAMBDAR-W);
//3-Taxa de inflação bruta dos salários
PIW = W - W(-1);
//4-Equação de Euler
(Pss/beta)*(LAMBDAR+P-LAMBDAR(+1))=(1-delta)*Pss*P(+1) + Rss*R(+1);
//5-Lei de movimento do capital
K = (1-delta)*K(-1) + delta*I;
//6-Lagrangiano da família não ricardiana
LAMBDANR = (sigma/((1-phic)*(1-phic*beta)))*(phic*beta*(CNR(+1)-phic*CNR)
-(CNR-phic*CNR(-1)))-P;
//7-Equação de Phillips para os salários da família não ricardiana
PIW = beta*PIW(+1)+((1-thetaW)*(1-beta*thetaW)/thetaW)*(LNR-LAMBDANR-W);
//8-Restrição orçamentária da família não ricardiana
P+CNR=W+LNR;
//9-Consumo agregado
Css*C = omegaR*CRss*CR + (1-omegaR)*CNRss*CNR;
//10-Trabalho agregado
Lss*L = omegaR*LRss*LR + (1-omegaR)*LNRss*LNR;
//11-Função de produção
Y = A + alpha*K(-1) + (1-alpha)*L;
//12-Demanda por capital
K(-1) = Y - R;
//13-Demanda por trabalho
L = Y - W;
//14-Custo marginal
CM = ((1-alpha)*W + alpha*R - A);
//15-Equação de Phillips
PI = beta*PI(+1)+((1-theta)*(1-beta*theta)/theta)*(CM-P);
//16-Taxa de inflação bruta
PI = P - P(-1);
//17-Condição de equilíbrio
Yss*Y = Css*C + Iss*I;
//18-Choque de produtividade
A = rhoa*A(-1) + e;
end;

model_diagnostics;
steady;
check (qz_zero_threshold=1e-20);

shocks;
var e;
stderr 0.01;
end;

stoch_simul(qz_zero_threshold=1e-20)Y I C CR CNR R K W L LR LNR PIW PI A;

Código cap 4

//Modelo NK com Rigidez de Salários -
//Capítulo 4 (ENTENDENDO OS MODELOS DSGE)
var Y I C R K W L PIW P PI A CM;
varexo e;
parameters sigma phi alpha beta delta rhoa psi theta thetaW psiW;

sigma = 2;
phi = 1.5;
alpha = 0.35;
beta = 0.985;
delta = 0.025;
rhoa = 0.95;
psi = 8;
theta = 0.75;
thetaW = 0.75;
psiW = 21;

model(linear);
#Pss = 1;
#Rss = Pss*((1/beta)-(1-delta));
#CMss = ((psi-1)/psi)*(1-beta*theta)*Pss;
#Wss = (1-alpha)*(CMss^(1/(1-alpha)))*((alpha/Rss)^(alpha/(1-alpha)));
#Yss = ((Rss/(Rss-delta*alpha*CMss))^(sigma/(sigma+phi)))*((1-beta*thetaW)
*((psiW-1)/psiW)*(Wss/Pss)*(Wss/((1-alpha)*CMss))^phi)^(1/(sigma+phi));
#Kss = alpha*CMss*(Yss/Rss);
#Iss = delta*Kss;
#Css = Yss - Iss;
#Lss = (1-alpha)*CMss*(Yss/Wss);
//1-Equação de Phillips para os salários
PIW = beta*PIW(+1)+((1-thetaW)*(1-beta*thetaW)/thetaW)*(sigma*C+phi*L-(W-P));
//2-Taxa de inflação bruta para os salários
PIW = W - W(-1);
//3-Equação de Euler
(sigma/beta)*(C(+1)-C)=(Rss/Pss)*(R(+1)-P(+1));
//4-Lei de movimento do capital
K = (1-delta)*K(-1) + delta*I;
//5-Função de produção
Y = A + alpha*K(-1) + (1-alpha)*L;
//6-Demanda por capital
K(-1) = Y - R;
//7-Demanda por trabalho
L = Y - W;
//8-Custo marginal
CM = ((1-alpha)*W + alpha*R - A);
//9-Equação de Phillips
PI = beta*PI(+1)+((1-theta)*(1-beta*theta)/theta)*(CM-P);
//10-Taxa de inflação bruta
PI = P - P(-1);
//11-Condição de equilíbrio
Yss*Y = Css*C + Iss*I;
//12-Choque de produtividade
A = rhoa*A(-1) + e;
end;

model_diagnostics;
steady;
check (qz_zero_threshold=1e-20);

shocks;
var e;
stderr 0.01;
end;

stoch_simul(qz_zero_threshold=1e-20) Y I C R K W L PI A;

Código cap 3

//Modelo NK - Capítulo 3 (ENTENDENDO OS MODELOS DSGE)
var Y I C R K W L CM P PI A;
varexo e;
parameters sigma phi alpha beta delta rhoa psi theta;

sigma = 2;
phi = 1.5;
alpha = 0.35;
beta = 0.985;
delta = 0.025;
rhoa = 0.95;
psi = 8;
theta = 0.75;

model(linear);
#Pss = 1;
#Rss = Pss*((1/beta)-(1-delta));
#CMss = ((psi-1)/psi)*(1-beta*theta)*Pss;
#Wss = (1-alpha)*(CMss^(1/(1-alpha)))*((alpha/Rss)^(alpha/(1-alpha)));
#Yss = ((Rss/(Rss-delta*alpha*CMss))^(sigma/(sigma+phi)))
*((Wss/Pss)*(Wss/((1-alpha)*CMss))^phi)^(1/(sigma+phi));
#Kss = alpha*CMss*(Yss/Rss);
#Iss = delta*Kss;
#Css = Yss - Iss;
#Lss = (1-alpha)*CMss*(Yss/Wss);
//1-Oferta de Trabalho
sigma*C + phi*L = W - P;
//2-Equação de Euler
(sigma/beta)*(C(+1)-C)=(Rss/Pss)*(R(+1)-P(+1));
//3-Lei de Movimento do Capital
K = (1-delta)*K(-1) + delta*I;
//4-Função de Produção
Y = A + alpha*K(-1) + (1-alpha)*L;
//5-Demanda por Capital
K(-1) = Y - R;
//6-Demanda por Trabalho
L = Y - W;
//7-Custo Marginal
CM = (1-alpha)*W + alpha*R - A;
//8-Equação de Phillips
PI = beta*PI(+1)+((1-theta)*(1-beta*theta)/theta)*(CM-P);
//9-Taxa de Inflação Bruta
PI = P - P(-1);
//10-Condição de Equilíbrio no Mercado de Bens
Yss*Y = Css*C + Iss*I;
//11-Choque de Produtividade
A = rhoa*A(-1) + e;
end;

steady;
check(qz_zero_threshold=1e-20);

shocks;
var e;
stderr 0.01;
end;

stoch_simul(nograph,qz_zero_threshold=1e-20) Y I C R K W L PI A;

Código cap 2

//Modelo RBC - Capítulo 2 (ENTENDENDO OS MODELOS DSGE)
//obs: W e R são reais na simulação

var Y I C R K W L A ;
varexo e;
parameters sigma phi alpha beta delta rhoa;

sigma = 2;
phi = 1.5;
alpha = 0.35;
beta = 0.985;
delta = 0.025;
rhoa = 0.95;

model(linear);
#Pss = 1;
#Rss = Pss*((1/beta)-(1-delta));
#Wss = (1-alpha)*(Pss^(1/(1-alpha)))*((alpha/Rss)^(alpha/(1-alpha)));
#Yss = ((Rss/(Rss-delta*alpha))^(sigma/(sigma+phi)))
*(((1-alpha)^(-phi))*((Wss/Pss)^(1+phi)))^(1/(sigma+phi));
#Kss = alpha*(Yss/Rss/Pss);
#Iss = delta*Kss;
#Css = Yss - Iss;
#Lss = (1-alpha)*(Yss/Wss/Pss);
//1-Oferta de trabalho
sigma*C + phi*L = W;
//2-Equação de Euler
(sigma/beta)*(C(+1)-C)=Rss*R(+1);
//3-Lei de movimento do capital
K = (1-delta)*K(-1)+delta*I;
//4-Função de produção
Y = A + alpha*K(-1) + (1-alpha)*L;
//5-Demanda por capital
R = Y - K(-1);
//6-Demanda por trabalho
W = Y - L;
//7-Condição de equilíbrio
Yss*Y = Css*C + Iss*I;
//8-Choque de produtividade
A = rhoa*A(-1) + e;
end;

steady;
check;
model_diagnostics;
model_info;

shocks;
var e;
stderr 0.01;
end;

stoch_simul;